BUILD.bazel

load(
    "@gz//bazel/skylark:build_defs.bzl",
    "GZ_FEATURES",
    "GZ_ROOT",
    "GZ_VISIBILITY",
    "gz_configure_header",
    "gz_export_header",
    "gz_include_header",
)
load(
    "@gz//bazel/lint:lint.bzl",
    "add_lint_tests",
)
load(
    "@rules_license//rules:license.bzl",
    "license",
)

package(
    default_applicable_licenses = [GZ_ROOT + "math:license"],
    default_visibility = GZ_VISIBILITY,
    features = GZ_FEATURES,
)

license(
    name = "license",
    package_name = "gz-math",
)

licenses(["notice"])

exports_files(["LICENSE"])

gz_configure_header(
    name = "config",
    src = "include/gz/math/config.hh.in",
    cmakelists = ["CMakeLists.txt"],
    package = "math",
)

gz_export_header(
    name = "include/gz/math/Export.hh",
    export_base = "GZ_MATH",
    lib_name = "gz-math",
    visibility = ["//visibility:private"],
)

public_headers_no_gen = glob([
    "include/gz/math/*.hh",
    "include/gz/math/detail/*.hh",
    "include/gz/math/graph/*.hh",
])

private_headers = glob(["src/*.hh"])

sources = glob(
    ["src/*.cc"],
    exclude = ["src/*_TEST.cc"],
)

gz_include_header(
    name = "mathhh_genrule",
    out = "include/gz/math.hh",
    hdrs = public_headers_no_gen + [
        "include/gz/math/config.hh",
        "include/gz/math/Export.hh",
    ],
)

public_headers = public_headers_no_gen + [
    "include/gz/math/config.hh",
    "include/gz/math/Export.hh",
    "include/gz/math.hh",
]

cc_library(
    name = "math",
    srcs = sources + private_headers,
    hdrs = public_headers,
    includes = ["include"],
    deps = [
        GZ_ROOT + "utils",
    ],
)

test_sources = glob(
    [
        "src/*_TEST.cc",
        "src/graph/*_TEST.cc",
    ],
)

[cc_test(
    name = src.replace("/", "_").replace(".cc", "").replace("src_", ""),
    srcs = [src],
    deps = [
        ":math",
        "@gtest",
        "@gtest//:gtest_main",
    ],
) for src in test_sources]

add_lint_tests()